1 files changed, 48 insertions, 0 deletions
diff --git a/games-action/vintage-story-bin/vintage-story-bin-1.22.3.ebuild b/games-action/vintage-story-bin/vintage-story-bin-1.22.3.ebuild
new file mode 100644
index 0000000..64d867a
--- /dev/null
+++ b/games-action/vintage-story-bin/vintage-story-bin-1.22.3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHECKREQS_DISK_BUILD="900M"
+inherit desktop check-reqs xdg
+
+DESCRIPTION="Uncompromising wilderness survival sandbox game (requires paid account)"
+HOMEPAGE="https://www.vintagestory.at/"
+SRC_URI="https://cdn.vintagestory.at/gamefiles/stable/vs_client_linux-x64_${PV}.tar.gz"
+S="${WORKDIR}/vintagestory"
+MY_PN="vintage-story"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+RESTRICT="bindist splitdebug strip mirror"
+
+RDEPEND="
+	>=virtual/dotnet-sdk-10.0
+	virtual/opengl
+	media-libs/openal
+	app-shells/bash
+"
+
+DIR="/opt/${MY_PN}"
+QA_PREBUILT="${DIR#/}/*"
+
+src_prepare() {
+	default
+	rm -v "${S}/install.sh" || die
+}
+
+src_install() {
+	insinto "${DIR}"
+	doins -r "${S}"/*
+	fperms +x "${DIR}/Vintagestory" "${DIR}/run.sh"
+
+	newicon -s 512 "${S}/assets/gameicon.png" ${MY_PN}.png
+	dosym "../..${DIR}/run.sh" /usr/bin/${MY_PN}
+	# niri tells me the app-id is literally 'Vintage Story', with space
+	# but make_desktop_entry says that's not allowed as a filename
+	# so i made up a fake reverse domain name kind of thing instead
+	make_desktop_entry --eapi9 ${MY_PN} -d 'at.vintagestory.Client' \
+					   -n 'Vintage Story' -c Game -i ${MY_PN} \
+					   -C 'Uncompromising wilderness survival sandbox game'
+}